home *** CD-ROM | disk | FTP | other *** search
/ Generous Efforts of Many / gemcd.zip / GEM.CD.A.po / FEATURES:BEAGLE / BEAGLE.BAG.SHK / BEAGLE.BAG / GAS CRUNCH.bas < prev    next >
BASIC Source File  |  2000-01-01  |  4KB  |  69 lines
  1. 30  REM <CTRL-M><CTRL-M>GAS CRUNCH<CTRL-M>BY BERT KERSEY<CTRL-M>BEAGLE BROS<CTRL-M>
  2. 32 Q =  -16384:QQ =  -16368:U =  -16336:G$ =  CHR$(7): ONERR  GOTO 63900
  3. 1010 N = 18
  4. 1015  HOME : INVERSE : VTAB 21: PRINT  SPC( 40): VTAB 21: HTAB 16: PRINT "GAS CRUNCH": GOSUB 1225: NORMAL 
  5. 1020  VTAB 22: PRINT "TAKE THE LAST CAN OF GAS, AND YOU LOSE!"
  6. 1021  REM <CTRL-J><CTRL-J>FLIP<CTRL-J>
  7. 1022  PRINT "         ---- ---             --- ----": PRINT "FLIP FOR FIRST:  HEADS OR TAILS (H/T):";: GET A$: PRINT A$: IF A$ =  CHR$(3)  OR A$ =  CHR$(27)  THEN ERR
  8. 1030  IF A$ < >"H"  AND A$ < >"T"  THEN  RUN 
  9. 1032  POKE QQ,0
  10. 1035  HOME : PRINT " FLIP-->";: FOR I = 1 TO 300: NEXT :J =  INT( RND(1) *2)
  11. 1040  FOR I = 1 TO 60: PRINT ":";: FOR II = 1 TO 3:S =  PEEK(U): NEXT : NEXT 
  12. 1045  INVERSE : IF J = 0  THEN  PRINT " HEADS ";
  13. 1046  IF J = 1  THEN  PRINT " TAILS ";
  14. 1047  NORMAL : PRINT G$
  15. 1050  FOR I = 1 TO 999: NEXT 
  16. 1055  IF (J = 1  AND A$ = "T")  OR (J = 0  AND A$ = "H")  THEN 1065
  17. 1057  PRINT "I WIN THE FLIP-- I GO FIRST..."
  18. 1060  GOTO 1125
  19. 1065  PRINT "YOU WIN THE FLIP--YOU GO FIRST..."
  20. 1070  FOR I = 1 TO 999: NEXT 
  21. 1075  REM <CTRL-J><CTRL-J>GET NUMBER<CTRL-J>
  22. 1080  HOME : PRINT "THE OBJECT IS TO NOT TAKE THE LAST CAN.": HTAB 18: PRINT "---          ---- ---"
  23. 1085  PRINT N;" LEFT. DO YOU TAKE 1, 2 OR 3 GAS CANS"
  24. 1090  COLOR= 15: PLOT 39,44: COLOR= 7: PLOT 39,45
  25. 1095 K =  PEEK(Q): IF K <176  OR K >185  THEN 1095
  26. 1096  POKE QQ,0
  27. 1100 K = K -176: IF K >0  AND K <4  THEN 1115
  28. 1105  HOME : PRINT "  NO WAY! YOU'VE GOTTA PUSH 1, 2 OR 3...                            -  -    -": GOTO 1085
  29. 1115  GOSUB 1157: HOME : PRINT "  YOU REMOVED ";CARD$: GOSUB 1190
  30. 1120  REM <CTRL-J><CTRL-J>APPLE'S TURN<CTRL-J>
  31. 1125  IF N = 1  THEN 1180
  32. 1127  IF N >16  OR N = 13  OR N = 9  OR N = 5  THEN 1135
  33. 1130 K = N -1 - INT((N -1)/4) *4: GOTO 1140
  34. 1135 K = 1
  35. 1140  GOSUB 1157: FOR I = 1 TO 999: NEXT 
  36. 1145  PRINT : PRINT "  MY TURN:  I REMOVE ";CARD$: IF N <11  THEN 1148
  37. 1146  FOR I = 1 TO 800: NEXT 
  38. 1148  GOSUB 1190
  39. 1150  IF N = 1  THEN 1165
  40. 1152  GOTO 1080
  41. 1155  GOTO 1090
  42. 1157 CARD$ = "ONE GAS CAN.": IF K = 2  THEN CARD$ = "TWO GAS CANS."
  43. 1158  IF K = 3  THEN CARD$ = "THREE GAS CANS."
  44. 1159  RETURN 
  45. 1160  REM <CTRL-J><CTRL-J>END<CTRL-J>
  46. 1165  HOME : PRINT "   YOU G<CTRL-G>ET THE L<CTRL-G>AST CAN-<CTRL-G>- YOU LO<CTRL-G>SE!": HTAB 27: PRINT "--- ----"
  47. 1170  FOR I = 1 TO 999: NEXT : GOTO 63900
  48. 1180  HOME : PRINT " RATS! YOU WON <CTRL-G>(<CTRL-G>#<CTRL-G>%<CTRL-G>&<CTRL-G>@<CTRL-G>!<CTRL-G>)<CTRL-G>! WHAT LUCK!": HTAB 8: PRINT "--- ---": GOTO 1170
  49. 1185  REM <CTRL-J><CTRL-J>REMOVE CANS<CTRL-J>
  50. 1190  COLOR= 0
  51. 1195  FOR I = 1 TO K
  52. 1200  IF N <7  AND N >0  THEN YY = 28
  53. 1201  IF N <13  AND N >6  THEN YY = 14
  54. 1202  IF N >12  THEN YY = 0
  55. 1205  FOR J = 3 +(N - INT(N/6) *6) *6 TO 7 +(N - INT(N/6) *6) *6
  56. 1210  VLIN YY,YY +10 AT J: FOR X = 1 TO 3
  57. 1215 S =  PEEK(U) + PEEK(U) - PEEK(U) - PEEK(U): NEXT : NEXT :N = N -1: NEXT : RETURN 
  58. 1220  REM <CTRL-J><CTRL-J>SET-UP CANS<CTRL-J>
  59. 1225  GR 
  60. 1230  COLOR= 15: HLIN 0,39 AT 11: HLIN 0,39 AT 39: HLIN 0,39 AT 25: VLIN 0,39 AT 0: VLIN 0,39 AT 39
  61. 1235  FOR I = 0 TO 28  STEP 14: FOR J = 3 TO 33  STEP 6
  62. 1245  COLOR= 5: HLIN J +1,J +3 AT I: PLOT J +1,I +1: PLOT J +3,I +1
  63. 1250  COLOR= 9: FOR II = J TO J +4: VLIN I +2,I +10 AT II: NEXT 
  64. 1255  COLOR= 13: HLIN J,J +1 AT I +4: HLIN J,J +3 AT I +5: HLIN J,J +4 AT I +6: HLIN J +1,J +4 AT I +7: HLIN J +3,J +4 AT I +8
  65. 1260  FOR II = 1 TO 25: NEXT : FOR II = 1 TO 4:S =  PEEK(U): NEXT : NEXT : NEXT : RETURN 
  66. 63900  NORMAL : VTAB 22: HTAB 1: CALL  -958: PRINT : PRINT "<M> MENU, <C> CONTINUE GAME, <Q> QUIT       SELECT:";: GET A$: PRINT A$: IF A$ = "C"  THEN  RUN 
  67. 63910  IF A$ = "M"  THEN  POKE 768,14: PRINT  CHR$(4);"RUN SHORT MENU"
  68. 63920  IF A$ = "Q"  THEN  VTAB 22: HTAB 1: CALL  -958: END 
  69. 63930  GOTO 63900